echo off
cls
if %1@==GemDoS@ goto s
shift
A:\GEMAPPS\GEMDOS GemDoS %0 %1 %2 %3 %4 %5 %6 %7 %8 %9
goto ab

** GEMDOS.BAT  Ver 1.6  28/FEB/1989  (c) M. Greenfield 1989 **

:s
attrib -r gemdos.bat
attrib +r %0.bat
del gemdos.bat
attrib -r %0.bat
cls

if %2@==@ goto q
if %2@==?@ goto h
if %2@==/@ goto h
shift
shift
if exist %0.bat goto b
if %0==type more<%1
if not %0==type %0 %1 %2 %3 %4 %5 %6 %7 %8 %9
pause
goto q

:b
command /c %0 %1 %2 %3 %4 %5 %6 %7 %8 %9
pause
goto q

:h
cls
echo  GEMDOS  -  A user friendly alternative to GEM's « Enter DOS Commands »
echo  ~~~~~~~
echo  1. Double clicking on the %0.BAT icon will cause a
echo     DOS Shell into its directory.  The icon can also be dragged using
echo     the mouse (i.e. copied) into any other directory and drive.
echo     Double clicking on the new copy will cause DOS Shell into the chosen
echo     directory,  followed by the subsequent removal of the new copy.
echo.
echo  2. A DOS command may be entered from within the GEM environment by typing
echo     into the OPEN APPLICATION window,  which appears after double clicking
echo     on the GEMDOS icon.  Any complex command may be typed,  inclusive of
echo     switches & arguments (but not: "| < > "),  e.g. TYPE {filename.ext}.
echo     (If the command is a batch file which is not in the directory shelled
echo     into, control will be returned to GEM immediately upon completetion.)
echo.
echo  NOTE: COMMAND.COM, ATTRIB.EXE, FIND.EXE & MORE.COM must be on the search path.
echo        ANSI.SYS must be installed (refer to DOS manual).
echo.
goto q

:ab
echo.
echo  This file must be placed in its specified directory, given in line 5.
echo  Correct, or edit line 5 of this program (shown below).
echo.
type GEMDOS.BAT|find "GEMDOS GemDoS"
echo [1A[K
pause
goto f

:q
echo     To  return to GEM, type:  EXIT    For help, type:  GEMDOS ?
if "%ε%"=="1" goto f
set ε=1
echo [2A
command
set ε=

:f